(hi hat)[17 c o 58 v G5 n]X
	[17 c o 47 v B5 n]x
	17 c 7 fb even 5 mul 15 a 8 r
	o sq 9 mul 15 a 8 r
(snare)[15G4 16 c G4 n 40{1 c- 1 m} T 40 - m]s.
	(body) 16 c 5 fb abs 15 a 11 d 5 s 6 r
	o 15 a 10 d 2 s 6 r
	(hiss) 15 c 7 fb abs 12 mul 15 a 0 r
	o 4 mul 15 a 6 r
(kick)[14 c G2 n 40{5 c- 1 m} T 40 - m]k.
	14 c 7 fb 12 a 9 r 50 v
	o sq 12 a 7 r
(bass)40 ←F[2 c o →F 1 + dup ←F v n]F↑
	[2 c o →F 1 - dup ←F v]F↓
	2 c amam 4 fb trem vib sus 6 a 56 v (sub bass)
	o 1 mul 4 a 12 r $F v ("filter")
	8 c 1 mul 12 a 3 d 0 r 50 v (main voice)
	o sq 1 mul 10 a 10 r 32 v (crackle)
(white noise)0 ←N[13 c o →N 1 + dup ←N v]↑
	13 c 7 fb 15 mul 15 a 0 r
	o sus 15 mul 15 a 1 r 0 v C5 n
(pluck + echo)[$plucks 1 !={1 c →plucks n 0 c $plucks n}]p 1 ←plucks
[0 G4 D5 G4 D5 0 G4 D5 D5 D#5 0 G4 F4 F4 G4 0 G4 F5 G4 D5 20 ⇐plucks]plucks
	[0 c rght 1 c left 6 c rght 7 c left]p→
	[0 c left 1 c rght 6 c left 7 c rght]p←
	50 7 55 6 40 1 60 0 4{exch c
	7 fb puls trem vib 2 mul 5 a 4 r 23 v
	o sine trem vib 2 mul 6 a 7 r exch v}
	0 c fmfm 1 c fmfm
(strings) 3{dup 10 + c
	2 fb half 9 a 5 r 46 v
	o half trem vib 1 mul 3 a 1 d 15 s 15 r 50 v}
(arp?) 3 c
	4 fb eabs trem 3 mul 7 a 5 r 48 v
	o eabs 6 a 3 r 52 v
(let's go!)
dv
60000 174 / 2 / t
2{4{G2 F↑ . . .} 2G2 . . 2G#2 . .}
T 2 / t
5{G2 F↑ x ↑ . ↑ . x ↑ . ↑ . dup 5 & ! !{x ↑ . ↑ .} dup 2 =={x ↑ . x ↑ .}}
G#2 F↑ x ↑ . ↑ . x ↑ . x ↑ .
4{G2 F↑ x ↑ . ↑ . x ↑ . ↑ . dup 1 == dup !{x ↑ . ↑ .}{x ↑ . x ↑ .}}
13 c mute 2 c mute . . . . s. . . . (drop) 13 c both o sus no 2 c both o 3 r
16{dup 1 &{pop dup 12 <{plucks F↓}0}
dup 4 | 7 =={10G4 11D5 12F5 13 c o 45 v C5 n}
dup 4 | 5 =={10D#4 11A#4 12C#5 13C5}
dup !{10F4 11C4 12A5 13C5}
p←
2G2 X k.		.	x .		.	X s.			.	2G2 p x .	.
p X .			.	p x k.	.	2G2 p X s.	.	p x .		.
p→
X k.			x .	2G2 x .	.	X s.			.	x p k.	.
2G2 p X .		.	p x k.	.	2G#2 p X s.	.	p x k.	x .
}
8{
dup 4 | 7 =={2G2 10G4 11D5 12F5}
dup 4 | 5 =={2D#2 10D#4 11A#4 12C#5}
dup !{2F2 10F4 11C4 12A5 13C5}
k.	.	.	.	s.	x .	.	.
.	.	k.	.	s.	.	k.	x .
.	.	.	.	s.	x .	k.	.
k.	.	.	.	s.	k.	.	x k.
}
T 2 / t 2 c mute o 45 v 8 c mute
[3 c 300 c+ . 700 c+ . 500 c- .]arp
13C5 2{
p← 3G3 . arp . arp . arp 3D3 . arp . arp . arp 3G3 . arp . arp
p→ . arp 3D3 . arp . arp . arp 3G3 dup ! dup !{.}{s.} arp . arp 3G#3 . arp . arp
}
2 c both 8 c both
1 ←bassline [$bassline 1 !={2 c →bassline n}]b
C2 Bb2 G2 D3 F3 5 ⇐bassline
F2 G2 F2 Bb2 G2 5 ⇐bassline
C3 D3 C3 Bb2 G2 5 ⇐bassline
C3 Bb2 G2 F2 D2 5 ⇐bassline
C2 D2 F2 Bb2 G2 5 ⇐bassline
5{plucks Bb2 F2 D2 D3 G2 D2 F2 G2 8 ⇐bassline
p←
b 3G3 X k. arp		b x . arp		b X s. arp			b 3D3 p x . arp
b p X . arp		p x k. arp		b 3G3 p X s. arp	p x . arp
p→
X k. . x . .			3D3 x . arp	b X s. arp			x p k. arp
b 3G3 p X . arp		p x k. arp		b 3G#3 p X s. arp	p x k. . x . .
p←
3G3 X k. arp		x . arp		b X s. arp			3D3 p x . arp
p X . arp			b p x k. arp	3G3 p X s. arp		p x . arp
p→
b X k. . x . .		3D3 x . arp	X s. arp			x p k. arp
b 3G3 p X . arp		p x k. arp		3G#3 p X s. arp		p x k. . x . .
}
8 c mute 2 c 51 dup ←sbv v [2 c →sbv 1 + dup ←sbv v ]sbv
13 c o sus 0 r 20 dup ←N v C5 n 2{
sbv 2G2 3G4 ↑ x s. arp	↑ x . arp			↑ x . arp		2G2 3D4 ↑ x . arp
sbv ↑ x . arp			↑ x . arp	2G2 3G4	↑ x . arp		↑ x . arp
sbv ↑ x . arp 2G2 ↑ x . arp ↑ x . arp ↑ x . arp
dup dup !{15 c both}{15 c mute}
sbv 2G2 3G4 ↑ x s. arp ↑ x . arp 2G#2 3G#4 ↑ x . arp ↑ x . arp
}
8 c both 13 c o sus 2 r 45 v
8{dup 1 & dup !{10D#4 11A#4 12C#5 13C5}
{plucks 10G4 11D5 12F5 13C5}
dup !{10F4 11C4 12A5 13C5}
p←
2G2 3G4 X k.		arp	x .			arp
X s.				arp	2G2 3D4 p x .	arp
p X .				arp	p x k.		arp
2G2 3G4 p X s.		arp	p x .			arp
p→
X k.				arp	2G2 x .		arp
X s.				arp	x p k.		arp
2G2 p X .			arp	p x k.		arp
2G#2 3G#3 p X s.	arp	p x k.		.	x .	.
}2 c mute 8 c mute
2{dup c amfm desq 7 fb 3 mul 1 a 2 r
	o puls 1 mul 6 a 5 r 57 v
	dup 6 + c desq 7 mul 10 a 1 r 43 v
	o desq 1 a 2 r}
T 128 * t 13C5
2{3{1G3 0G3 .} 1G#3 0G#3 .}